##  NSUSERS.XEQ - Display all VT users and their machine name.
##  Doug Werth                      Beechglen Development Inc.
##  doug@beechglen.com                        Cincinnati, Ohio
##
##  Modified by Tim Ericson at Denkor Dental Management
##    To ignore local connections to other machines

echo
echo VT Users Logged on as of !hpdatef @ !hptimef
echo

setvar holdmsgfence, hpmsgfence
setvar hpmsgfence, 2

purge NSWork,temp > $null

setvar SessNum, " "
setvar SessionName, " "
setvar WorkStationID, " "

build NSWork; temp; rec=-80,,f,ascii;msg
file out=NSWork,oldtemp
nscontrol status=users > *out
reset out

Echo Session   Logon                       Workstation/Machine
Echo --------  --------------------------  -------------------------------

while finfo("NSWork","EOF") > 0
   input NSWorkRec < NSWork
   if lft(NSWorkRec,1) = "#" and str(NSWorkRec,17,6) = "REMOTE"
      setvar SessNum lft(NSWorkRec,8)
      setvar SessionName str(NSWorkRec,31,26)
      input NSWorkRec < NSWork
      while str(NSWorkRec,19,6) <> "ORIGIN"
         input NSWorkRec < NSWork
      endwhile
      setvar WorkStationID rtrim(str(NSWorkRec,33,40))

      Echo !SessNum  !SessionName  !WorkStationID

   endif
endwhile

Echo

purge NSWork,temp
setvar hpmsgfence, holdmsgfence
deletevar holdmsgfence
deletevar SessNum
deletevar SessionName
deletevar WorkStationID
deletevar NSWorkRec