rem
rem alert batch file for Water detector alarms
rem parm1=Ipaddr parm2=msg parm3=severity ($s) parm4=$1 from ups msg
rem (severity= CRITICAL| Major| Warning| Minor |Normal )
rem Used with water sensors hooked up to relay inputs on an APC Smartslot card
rem ups in data center (ups1/10.1.1.13) with water sensors attached is hard coded (see below)
rem
rem 10/12/01 Chris Bartram
rem 07/20/04 Replaced OperationsFYI with OperationsL
rem 05/03/06 Added logic for overlapping NNM servers and failover
rem

set TELOPTIONS=-holdifsent -holdrefresh -releasewait 10m -check "Ups at %1:%2"
set STATIONB=OVNNMB
set STATIONA=OVNNMA
set FAILOVERFILE=C:\INFAILOVER.SWI
set statb=0
set stata=0

if /I "%COMPUTERNAME%"=="OVNNMB" GOTO OVNNMB
if /I "%COMPUTERNAME%"=="WDCNMG02" GOTO WDCNMG02
if /I "%COMPUTERNAME%"=="OVNNMA" GOTO OVNNMA
GOTO SETUPEND

:OVNNMB

set statb=1
set TELIPLIST=10.102.91.11,10.102.88.152
GOTO SETUPEND

:WDCNMG02

set statb=1
set TELIPLIST=10.102.91.11,10.102.88.152
GOTO SETUPEND

:OVNNMA

set stata=1
set TELIPLIST=10.102.88.152,10.102.91.11
GOTO SETUPEND

:SETUPEND

IF EXIST %FAILOVERFILE% GOTO FAILOVER
GOTO STARTBAT

:FAILOVER

set statb=1
set stata=1

:STARTBAT

IF "%1"=="10.1.1.13" GOTO XP001
IF /I "%1"=="apcups1" GOTO XP001
GOTO XP002

:XP001
rem Relays hooked up to Water Sensors in Computer Room

if %stata%==0 GOTO ENDBAT

telalertc -g Operations -m "Bldg A:DC:Water detected under floor in zone %4" -subject "TelAlert:Environment" -check "Operations:Water Zone %4" -delay 5m
telalertc -g OperationsL -m "Bldg A:DataCenter:Water detected under floor in zone %4" -subject "TelAlert:Environment" -check "OperationsL:Water Zone %4" -delay 5m
telalertc -g OMS -m "Bldg A:DataCenter:Water in zone %4" -subject "TelAlert:Environment" -check "OMS:Water Zone %4" -delay 5m
telalertc -i speaker -m "water in computer room location %4"
telalertc -i HelpDeskBoard -m "TA:down water-detected Bldg A CompRoom zone %4" -check "HelpDeskBoard:Water Zone %4" -delay 5m

GOTO ENDBAT

:XP002

rem Relays hooked up to Water Sensors in Computer Room
telalertc -i DataCenterManagerWorkEmail -m "Relay at %1 Tripped zone %4" -subject "TelAlert:Environment"

telalertc -g Operations -m "Relay at %1 Tripped zone %4" -subject "TelAlert:Environment"

:ENDBAT

EXIT /B 0