!JOB ABORTS01, MANAGER.SYS,PUB;OUTCLASS=LP,1;PRI=CS;INPRI=10;SPSAVE
!
!COMMENT *** THIS JOB ABORTS ALL SESSIONS EXCEPT ONES LOGGED ON IN SYS
!
!COMMENT *** JOSEPH ROSENBLATT
!
!COMMENT It is a simple job that aborts all users on the system,
!COMMENT except the users logged on in the SYS account. It uses
!COMMENT utilities FCOPY, CI and EDITOR, available with the 5.0
!COMMENT and above FOS. One can substitute the editor of one's
!COMMENT choice. One can also modify the editing to fit ones needs,
!COMMENT modifying the exceptions etc.
!
!COMMENT *** PURGE WORK FILES BEFORE CREATING THEM IN JOB STREAM
!
!PURGE ABSES01.PUB.SYS
!PURGE ABSES02.PUB.SYS
!PURGE ABSES03.PUB.SYS
!
!
!COMMENT *** CREATE A FILE FROM A SHOWJOB LISTING
!
!SHOWJOB JOB=@S;EXEC
!SHOWJOB JOB=@S;EXEC > ABSES01
!SAVE ABSES01
!
!COMMENT *** EDIT INPUT FILE
!COMMENT *** REMOVE HEADER/TRAILER LINES AND ANY ".SYS" LOG ON
!
!RUN EDITOR.PUB.SYS
TEXT  ABSES01
D 1/3
D ".SYS"
D LAST-4/LAST
KEEP
YES
EXIT
!
!COMMENT *** CREATING FILE ABSES02 - JUST THE SESSION # (#SNNN)
!
!SETVAR ABSESEOF FINFO("ABSES01",19)
!BUILD ABSES02;REC=-7,1,F,ASCII;DISC=!ABSESEOF
!FCOPY FROM=ABSES01;TO=ABSES02;NOUSERLABELS
!
!COMMENT *** CREATING FILE ASSES03 - ADD 10 BLANK BYTES
!COMMENT *** THIS IS NEEDED TO ADD "ABORTJOB " TO FILE
!
!BUILD ABSES03;REC=-17,1,F,ASCII;DISC=!ABSESEOF
!FCOPY FROM=ABSES02;TO=ABSES03;NOUSERLABELS
!
!COMMENT *** EDIT ABSES03 - ADD ABORTJOB
!
!RUN EDITOR.PUB.SYS
TEXT  ABSES03
CQ "#" TO "ABORTJOB #" IN FIRST/LAST
KEEP
YES
EXIT
!
!COMMENT *** RUN COMMAND FILE ABSES03
!COMMENT ***THIS WILL ABORT ALL SESSIONS EXCEPT ONES LOGGED ON IN SYS
!
!LIMIT ,0
!
!ABSES03
!
!EOJ