parm input=" " jobsess="@" entry="main" quietin="n"

# DEVID.XEQ - DISPLAY USER/JOB INFO.
# JOHN DUNLOP

setvar inp ups("!input")
setvar cvar 0
setvar svar 0
setvar quiet "!quietin"
setvar js ups("!jobsess")
if "!entry" = "main"
  if "!inp" = " "  or len("!inp") < 2
    echo
    echo  DEVID : Displays User/Job info based on selection criteria.
    echo
    echo Usage:DEVID [S]XXXXX[.]XXX J
    echo                            S
    echo
    echo       where [S]XXXXX[.]XXX = Session number(with prefix S)
    echo                              or  Ldev number(number only)
    echo                              or  User.Account
    echo                              or  a "string" to search on.
    echo           Note : "string" must be more than one character.
    echo                            J = search ONLY Jobs
    echo                            S = search ONLY Sessions
    echo                                Default (e.g. neither = search &
                             all)
    echo
    echo This will show Session,Ldev and user name of selection
  else
    purge temp,temp > $null
    if "!quiet" <> "y"
      echo
    endif
    setvar occurs 0
    if pos(".","!inp") > 0
      if "!quiet" <> "y"
        echo ===!> Searching for all users logged on as !INP
        echo
      endif
      showjob job=!inp > temp
    else
      setvar instr str("!inp",2,8)
      if pos("S","!inp") > 0 and typeof(!instr) = 1
        if "!quiet" <> "y"
          echo ===!> Searching for Session #!inp
          echo
        endif
        showjob #!inp > temp
      else
        if typeof(!inp) = 1
          if "!quiet" <> "y"
            echo ===!> Searching for Session on Ldev !inp
            echo
          endif
          showdev !inp > temp1
          showdev !inp
          if "!quiet" <> "y"
            echo
          endif
          devid ,"!js","dev","!quiet" < temp1
          if !svar > 0
            showjob #!inp > temp
          else
            return
          endif
        else
          if typeof(!inp) <> 1
            if "!quiet" <> "y"
              if "!js" = "@"
                echo ===!> Searching for All Users Containing !inp
                echo
              elseif "!js" = "J"
                echo ===!> Searching for All Jobs Containing !inp
                echo
              elseif "!js" = "S"
                echo ===!> Searching for All Sessions Containing !inp
                echo
              endif
            endif
            showjob job=@ > temp
            devid "!inp","!js","string","!quiet" < temp
            if "!quiet" <> "y"
              echo
            endif
              return
          endif
        endif
      endif
    endif
    devid ,"!js","level2","!quiet" < temp
    if "!quiet" <> "y"
      echo
    endif
  endif
else
  if "!entry" = "level2"
    setvar eof finfo("temp","eof")
    setvar rec_count 0
    while rec_count < eof do
      input rec < temp
      if pos("#","!rec") > 0 and pos("#1","!rec") = 0
        echo !rec
        setvar occurs !occurs + 1
      endif
      setvar rec " "
      setvar rec_count rec_count + 1
    endwhile
  else
    if "!entry" = "dev"
      setvar eof finfo("temp1","eof")
      setvar rec_count 0
      while rec_count < eof do
        input rec < temp1
        setvar svar pos("#","!rec")
        setvar cvar pos(":","!rec")
        if !svar > 0  and pos("#1","!rec") = 0
          setvar inp str("!rec",(!svar + 1 ),((!cvar - 1 ) - !svar))
          return
        endif
        setvar rec " "
        setvar rec_count rec_count + 1
      endwhile
    else
      if "!entry" = "string"
        setvar eof finfo("temp","eof")
        setvar rec_count 0
        setvar hion chr(27) + "&dB"
        setvar hioff chr(27) + "&d@"
        while rec_count < eof do
          input rec < temp
          if len("!rec") > 1
            setvar js_sel str("!rec",2,1)
          endif
          if pos("!inp","!rec") > 0 and pos("#","!rec") > 0  and &
             (("!js" = "!js_sel" or "!js" = "@"))
            setvar str_begin pos("!inp","!rec") - 1
          setvar str_len len("!inp")
          setvar tot len("!rec")
          setvar rest !str_begin + 1 + !str_len
          setvar string1 lft("!rec",!str_begin )
          setvar string2 str("!rec",!str_begin + 1, !str_len)
          if !tot > !str_begin + !str_len
            setvar string3 str("!rec",!rest,(!tot + 5 - !rest))
          else
            setvar string3 ""
          endif
          setvar outstr "!string1" + "!hion" + "!string2" + "!hioff"
          setvar outstr "!outstr" + "!string3"
          setvar occurs !occurs + 1
          echo !outstr
          deletevar str_begin,str_len,tot,rest,
          deletevar outstr,string1,string2,string3
        endif
       setvar rec " "
       setvar rec_count rec_count + 1
       endwhile
     endif
    endif
  endif
   if "!quiet" <> "y"
     echo
     if !occurs = 0
        echo *** No occurrences found ***   [!hptimef  !hpdatef]
     elseif !occurs = 1
        echo *** !occurs occurrence found ***   [!hptimef  !hpdatef]
         else
           echo *** !occurs occurrences found ***   [!hptimef &
             !hpdatef]
     endif
     echo
   endif
endif