PARM F1,F2=0,F3=0,F4=0,F5=0,F6=0,F7=0,F8=0,F9=0,F10=0,F11=0,F12=0
##  DS.XEQ - BRUTE FORCE DELETE SPOOL FILES
##           "ME" AS ARGUMENT 1 WILL DELETE
##           ALL SPOOL FILES FOR CURRENT LOGON USER.
##  TIM ERICSON
IF UPS("!F1") = "ME"
  SPOOLF O@;SELEQ=[JOBNUM=!HPJOBTYPE!HPJOBNUM];DELETE
  RETURN
ENDIF
SETVAR FNUM 1
SETVAR FNAME "!!F" + "!FNUM"
WHILE FNUM <= 12 AND "!FNAME" <> "0" DO
  IF NUMERIC("!FNAME")
    SPOOLF #O!FNAME;DELETE
  ELSEIF ( LFT("!FNAME",1)="O" AND &
       NUMERIC(RHT("!FNAME",LEN("!FNAME")-1)) )
    SPOOLF !FNAME;DELETE
  ELSEIF ( ( LFT("!FNAME",2)="J'" OR LFT("!FNAME",2)="S'" ) AND &
       NUMERIC(RHT("!FNAME",LEN("!FNAME")-2)) ) &
  OR ( ( LFT("!FNAME",1)="J" OR LFT("!FNAME",1)="S" ) AND &
       NUMERIC(RHT("!FNAME",LEN("!FNAME")-1)) )
    SPOOLF O@;SELEQ=[JOBNUM=!FNAME];DELETE
  ELSEIF ( LEN("!FNAME")<>1 AND &
       NOT NUMERIC(RHT("!FNAME",LEN("!FNAME")-1)) )
    SPOOLF O@;SELEQ=[FILEDES=!FNAME];DELETE
  ENDIF
  SETVAR FNUM FNUM + 1
  SETVAR FNAME "!!F" + "!FNUM"
ENDWHILE
DELETEVAR FNUM
DELETEVAR FNAME