parm select ="@" entry='MaIn'

# Command file:  lfeq      1997/05/06
# Author:        Paul H. Christidis  : phchristidis@west.raytheon.com
# Remarks:       Will list file equations containing specified sub-
#                string.

setvar mpexfinfoany 1
if "!entry" = "ReAdIt" then
  input _leq_text
  input _leq_text
  input _leq_text
  setvar _leq_count 0
  echo
  while (POS("$eod$",(SETVAR(_leq_text,INPUT()))) = 0) do
    if LEN(_leq_text) > 6 then
       if pos("!_leq_select",RHT(_leq_text,-7)) <> 0 then
          echo !_leq_text
          setvar _leq_count _leq_count + 1
       endif
    endif
  endwhile
#  (return to myself in the "main" entry code)
  return
else
   setvar _leq_select ups("!select")
   if "!_leq_select" = "@" then
      listeq
   else
      echo ** File equations for: !_leq_select **
      continue
      listeq > xleqfilx
      echo $eod$ >> xleqfilx
      xeq !hpfile _leq_select ;entry="ReAdIt"  < xleqfilx
      purge xleqfilx,temp > $null
      echo
      if _leq_count = 1 then
         echo **** !_leq_count Equation qualified. **** ![chr(7)]
      else
         echo **** !_leq_count Equations qualified. **** ![chr(7)]
      endif
   endif
endif
deletevar mpexfinfoany
if bound(traceon) then
   showvar   _leq@
else
   deletevar _leq@
endif