PARM FILE,START=1,PAGE=23,PARM=" "
##  P.XEQ - PRINT THE CONTENT OF MULTIPLE FILE TYPES
##  TIM ERICSON
IF NUMERIC("!FILE")
  IF NOT FINFO("O!FILE.OUT.HPSPOOL",0)
    ECHO NONEXISTENT FILE: O!FILE.OUT.HPSPOOL
    RETURN
  ENDIF
  PRINT O!FILE.OUT.HPSPOOL;START=!START;PAGE=!PAGE;!PARM
  RETURN
ENDIF
IF ( LFT("!FILE",1)="O" AND &
     NUMERIC(RHT("!FILE",LEN("!FILE")-1)) )
  IF NOT FINFO("!FILE.OUT.HPSPOOL",0)
    ECHO NONEXISTENT FILE: !FILE.OUT.HPSPOOL
    RETURN
  ENDIF
  PRINT !FILE.OUT.HPSPOOL;START=!START;PAGE=!PAGE;!PARM
  RETURN
ENDIF
IF ( ( UPS(LFT("!FILE",1))="J" ) AND &
     NUMERIC(RHT("!FILE",LEN("!FILE")-1)) ) &
OR ( ( UPS(LFT("!FILE",2))="#J" ) AND &
     NUMERIC(RHT("!FILE",LEN("!FILE")-2)) )
  SETJCW CIERROR,0
  LISTSPF O@;SELEQ=[JOBNUM=!FILE AND FILEDES="$STDLIST"] > LSFILE
  IF CIERROR <> 0
    ECHO NONEXISTENT $STDLIST FOR !FILE
  ELSE
    SETVAR FIRST_CHAR, "A"
    SETVAR LINE_NUMBER, 4
    WHILE FIRST_CHAR <> "$"
      PRINT LSFILE;START=!LINE_NUMBER > PRFILE
      INPUT LSREC < PRFILE
      SETVAR FIRST_CHAR, STR(LSREC,21,1)
      SETVAR LINE_NUMBER, LINE_NUMBER + 1
    ENDWHILE
    SETVAR LSREC, RTRIM(STR(LSREC,02,10)," ") + ".OUT.HPSPOOL"
    PRINT !LSREC;START=!START;PAGE=!PAGE;!PARM
    DELETEVAR FIRST_CHAR, LINE_NUMBER, LSREC
    PURGE PRFILE,TEMP
  ENDIF
  PURGE LSFILE,TEMP
  RETURN
ENDIF
IF NOT FINFO("!FILE",0)
  ECHO NONEXISTENT FILE: !FILE
  RETURN
ENDIF
PRINT !FILE;START=!START;PAGE=!PAGE;!PARM