parm entry=""

comment  This command file scans all groups for missing passwords
comment  and generates a passwords for those groups with special
comment  capabilities. Lars Appel 5/93.

if "!entry" = "" then
  file newpass=$newpass;rec=-80,,f,ascii
  listgroup @.@;pass > *newpass
  reset newpass
  echo Scanning system for missing PM group passwords...
  setvar _me "!-1"
  !_me sub1 < $oldpass
  deletevar _@
  echo Task completed.
endif

if "!entry" = "sub1" then
  setvar _n finfo("$oldpass","eof")/14
  setvar _k 0
  while _k < _n do
    input _x
    input _g
    setvar _g str(_g,8,17)
    input _x
    input _p
    setvar _p str(_p,43,8)
    setvar _m 9
    while _m > 0 do
      input _x
      setvar _m _m-1
    endwhile
    input _c
    setvar _c str(_c,6,72)
    if "!_p" = "        " then
      if pos("PM",_c) > 0 then
        setvar _p lft(_g,pos(".",_g)-1)
        altgroup !_g;pass=!_p
        echo Missing password for !_g has been set.
      endif
    endif
    setvar _k _k+1
  endwhile
endif