parm users="@.@",mode="preview",entry=""

comment  This command file scans all users for missing passwords
comment  and generates a passwords for those users with special
comment  capabilities. Lars Appel 5/93.

comment  17.01.95 Lars: new parameters "users" and "mode"

if "!entry" = "" then
  file newpass=$newpass;rec=-80,,f,ascii
  listuser !users;pass > *newpass
  reset newpass
  echo Scanning system for missing SM/OP/PM user passwords...
  setvar _me "!-1"
  !_me ;entry="sub1" < $oldpass
  if ups("!mode") = "PREVIEW" then
    echo Users have not been changed due to PREVIEW mode
  elseif ups("!mode") = "SIMPLE" then
    echo Users have been changed using SIMPLE mode
  elseif ups("!mode") = "RANDOM" then
    echo Users have been changed using RANDOM mode
  elseif ups("!mode") = "REMOVE" then
    echo User passwords have been removed
  else
    echo Users have been changed using fixed password
  endif
  deletevar _@
  echo Task completed.
endif

if "!entry" = "sub1" then
  setvar _n finfo("$oldpass","eof")/7
  setvar _k 0
  while _k < _n do
    input _x
    input _u
    setvar _u str(_u,7,17)
    input _x
    input _p
    setvar _p str(_p,43,8)
    input _x
    input _x
    input _c
    setvar _c str(_c,6,72)
    if ups("!mode") = "REMOVE" then
      echo !_u
      altuser !_u;pass=
    elseif "!_p" = "        " then
      if (pos("SM",_c) > 0) or (pos("OP",_c) > 0) or (pos("PM",_c) > 0) then
        echo !_u
        if ups("!mode") = "PREVIEW" then
          comment  do nothing
        elseif ups("!mode") = "SIMPLE" then
          setvar _p lft(_u,pos(".",_u)-1)
          altuser !_u;pass=!_p
        elseif ups("!mode") = "RANDOM" then
          setvar _p lft(_u,1)+rht("0!hpdate",2)+rht("0000!hpcpumsecs",5)
          altuser !_u;pass=!_p
        else
          altuser !_u;pass=!mode
        endif
      endif
    endif
    setvar _k _k+1
  endwhile
endif