parm spid=*,selopt=*,selparm=*,option=*

# FILENAME: SPLLIST.XEQ - Joe Geiser
#
# Command file to 'front-end' the NMS LISTSPF
#  seleq syntax.
# Valid seleq options are: DEV,FILEDES,SPOOLID,
#  STATE,JOBNAME,JOBNUM,DISP,OWNER,COPIES,PRI.
# Inputting SPLLIST H will display help.

setvar errors,false
setvar spoolid,ups("!spid")
if "!spoolid" = "H"
  echo SPLLIST command usage options.............
  echo   :SPLLIST [spoolid [,selopt,selparm[,listopt]]]
  echo Where:
  echo  spoolid defaults to all spoofles created by your
  echo    user.account but can be optionally specified as O@ or
  echo    a valid spoofle number.
  echo  selopt is an optional spoofle selection option,
  echo    and can be one of OWNER, DEV, FILEDES, SPOOLID,
  echo    STATE, JOBNAME, JOBNUM, DISP, COPIES, or PRI.
  echo  selparm is an optional spoofle selection value which
  echo    must be specified if you specify a selop. For example,
  echo    you must enter a 'user.account' selparm if you enter
  echo    'owner' as the selopt.
  echo  listopt can be optionally specified as DETAIL or STATUS.
  echo    It will produce the appropriate LISTSPF output.
  echo  Examples:
  echo    :SPLLIST,OWNER,PREMIUM.VISMULTI
  echo    :SPLLIST,STATE,READY,DETAIL
  echo  See 'HELP LISTSPF OPERATION' for more info.
else
  echo Type  :SPLLIST H  for help.
  if "!spoolid" = "*" and "!selopt" = "*" and "!selparm" = "*"
    setvar listspf,"listspf;seleq=[owner=!hpuser.!hpaccount]"
  else
    if "!spoolid" = "*"
      setvar listspf,"listspf o@"
    else
      setvar listspf,"listspf " + "!spoolid"
    endif
    if "!selopt" <> "*"
      setvar uselopt,ups("!selopt")
      if "!uselopt" <> "OWNER" and "!uselopt" <> "DEV" &
        and "!uselopt" <> "FILEDES" and "!uselopt" <> "STATE" &
        and "!uselopt" <> "JOBNUM" and "!uselopt" <> "JOBNAME" &
        and "!uselopt" <> "SPOOLID" and "!uselopt" <> "DISP" &
        and "!uselopt" <> "COPIES" and "!uselopt" <> "PRI"
        echo '!selopt' is invalid. Valid selection keywords are:
        echo    OWNER, DEV, FILEDES, STATE, JOBNUM, JOBNAME,
        echo    SPOOLID, DISP, COPIES, PRI.
        setvar errors,true
      else
      setvar listspf,"!listspf" + ";seleq=[" + "!selopt" &
         +"="+"!selparm"+"]"
      endif
      deletevar uselopt
    endif
  endif
  if "!option" <> "*"
    setvar uoption,ups("!option")
    if "!uoption" <> "DETAIL" and "!uoption" <> "STATUS"
      echo '!option' is invalid. Valid :SPLLIST options are:
      echo   DETAIL,STATUS.
      setvar errors,true
    else
      setvar listspf,"!listspf"+";"+"!option"
    endif
    deletevar uoption
  endif
  if not errors
!listspf
  endif
  deletevar errors,spoolid,listspf
endif