parm sp_option="S"

# FILENAME: SPLPURGE.XEQ - Joe Geiser
#
# Command files SPLPURGE, SPLPURGS, SPLPURGA, SPLPURGI
#  will purge spoofles. ':SPLPURGE ' will execute
#  'SPLPURGS', purging spoofles for the current logon
#  job/session. ':SPLPURGE A' will execute 'SPLPURGA',
#  purging all spoofles for logon user.account.
#  ':SPLPURGE XXXX' will execute 'SPLPURGI', purging
#  spoofles for job/session id XXXX (eg, J123, S4444).

setvar sp_optn,ups("!sp_option")
if "!sp_optn" = "H"
  echo
  echo SPLPURGE command sp_options.............
  echo To delete all spoofles for current logon job/session,
  echo     use   :SPLPURGE
  echo To delete all spoofles for your MPE user.account,
  echo     use   :SPLPURGE A
  echo To delete all  spooflesm for a specific job/session number,
  echo     use   :SPLPURGE Jxxx   :SPLPURGE Sxxx
  echo     (you must have appropriate MPE access)
  echo
else
  echo Type ':SPLPURGE H' for help.
  FILE listspf=listspf,NEW;REC=-79,,F,ASCII;DEV=DISC;NOCCTL;TEMP
  FILE IN=listspf;REC=-79
  if "!sp_optn" = "S"
     run ci.pub.sys;stdlist=*listspf;info="listspf";parm=3
     RUN CI.PUB.SYS;INFO="SPLPURGS.XEQ &
          ![FINFO("listspf",19)]";PARM=2;STDIN=*IN
     echo All spoofles for current job/session deleted.
  elseif  "!sp_optn" = "A"
     run ci.pub.sys;stdlist=*listspf;info="listspf";parm=3
     RUN CI.PUB.SYS;INFO="SPLPURGA.XEQ &
          ![FINFO("listspf",19)]";PARM=2;STDIN=*IN
     echo All spoofles for user !hpuser.!hpaccount deleted.
  else
     run ci.pub.sys;stdlist=*listspf;info="listspf o@";parm=3
     RUN CI.PUB.SYS;INFO="SPLPURGI.XEQ &
          ![FINFO("listspf",19)]";PARM=2;STDIN=*IN
     echo All spoofles for job/session !sp_optn deleted.
  endif
  purge listspf,temp
endif
DELETEVAR SP@