PARM FILE,START=0,PAGE=23,PARM=" "
##  TAIL.XEQ - PRINT THE LAST 23 LINES OF MULTIPLE FILE TYPES
##  TIM ERICSON
IF !START = 0
  SETVAR LINE, 2 - !PAGE
ELSE
  SETVAR LINE, 2 - !START
ENDIF
IF NUMERIC("!FILE")
  IF NOT FINFO("O!FILE.OUT.HPSPOOL",0)
    ECHO NONEXISTENT FILE: O!FILE.OUT.HPSPOOL
    RETURN
  ENDIF
  PRINT O!FILE.OUT.HPSPOOL;START=!LINE;PAGE=!PAGE;!PARM
  RETURN
ENDIF
IF ( LFT("!FILE",1)="O" AND &
     NUMERIC(RHT("!FILE",LEN("!FILE")-1)) )
  IF NOT FINFO("!FILE.OUT.HPSPOOL",0)
    ECHO NONEXISTENT FILE: !FILE.OUT.HPSPOOL
    RETURN
  ENDIF
  PRINT !FILE.OUT.HPSPOOL;START=!LINE;PAGE=!PAGE;!PARM
  RETURN
ENDIF
IF ( ( UPS(LFT("!FILE",1))="J" ) AND &
     NUMERIC(RHT("!FILE",LEN("!FILE")-1)) ) &
OR ( ( UPS(LFT("!FILE",2))="#J" ) AND &
     NUMERIC(RHT("!FILE",LEN("!FILE")-2)) )
  SETJCW CIERROR,0
  LISTSPF O@;SELEQ=[JOBNUM=!FILE AND FILEDES="$STDLIST"] > LSFILE
  IF CIERROR <> 0
    ECHO NONEXISTENT $STDLIST FOR !FILE
  ELSE
    SETVAR FIRST_CHAR, "A"
    SETVAR LINE_NUMBER, 4
    WHILE FIRST_CHAR <> "$"
      PRINT LSFILE;START=!LINE_NUMBER > PRFILE
      INPUT LSREC < PRFILE
      SETVAR FIRST_CHAR, STR(LSREC,21,1)
      SETVAR LINE_NUMBER, LINE_NUMBER + 1
    ENDWHILE
    SETVAR LSREC, RTRIM(STR(LSREC,02,10)," ") + ".OUT.HPSPOOL"
    PRINT !LSREC;START=!LINE;PAGE=!PAGE;!PARM
    DELETEVAR FIRST_CHAR, LINE_NUMBER, LSREC
    PURGE PRFILE,TEMP
  ENDIF
  PURGE LSFILE,TEMP
  RETURN
ENDIF
IF NOT FINFO("!FILE",0)
  ECHO NONEXISTENT FILE: !FILE
  RETURN
ENDIF
PRINT !FILE;START=!LINE;PAGE=!PAGE;!PARM