##  VTUSERS.XEQ - LIST SHOWCONN INFO FOR REMOTE VT USERS ONLY
##  DOUG WERTH, DAVID HUTCHINSON, AND TIM ERICSON

setvar holdmsgfence, hpmsgfence
setvar hpmsgfence, 2

purge NSWork, temp > $null
build NSWork; temp; rec=-80,,f,ascii; msg
file out=NSWork,oldtemp
nscontrol status=users > *out
reset out

PURGE TCPIP2, TEMP > $NULL
BUILD TCPIP2; TEMP; REC=-80,,F,ASCII; DEV=DISC; DISC=1000
FILE X=TCPIP2,OLDTEMP; DEV=DISC; ACC=APPEND

while finfo("NSWork","EOF") > 0
   INPUT RECORD < NSWork
   if lft(RECORD,1) = "#" and str(RECORD,17,6) = "REMOTE"
      ECHO SHOWCONN JOB=![LFT(RECORD,8)] > *X
   ENDIF
endwhile

reset X
purge NSWork, temp

purge TEMPFILE, temp > $null
build TEMPFILE; temp; rec=-72,,f,ascii; msg
file out=TEMPFILE, oldtemp
TCPIP2 > *out
reset out

ECHO JOBNUM  INTRO DATE AND TIME    LDEV   USERNAME
ECHO  REMOTE ADDRESS  RPORT  LPORT  FLAGS   PIN(PROGRAM)

WHILE FINFO("TEMPFILE","EOF") > 0
   INPUT RECORD < TEMPFILE
   IF LFT(RECORD,1) = '#'
      ECHO !RECORD
      INPUT RECORD < TEMPFILE
      ECHO !RECORD
   ENDIF
   SETVAR RECORD  "                                           "
ENDWHILE

PURGE TCPIP2, TEMP
PURGE TEMPFILE, TEMP
DELETEVAR RECORD

setvar hpmsgfence, holdmsgfence
deletevar holdmsgfence