%META:TOPICINFO{author="ChrisBartram" date="1149893023" format="1.1" version="1.1"}%
%META:TOPICPARENT{name="Hp3000MpexXeqs"}%
<pre>
PARM accfile="?"
PARM typem="T"
ANYPARM msg=""
COMMENT ***********************************************
COMMENT    THIS COMMAND FILE SENDS A TELL MESSAGE TO
COMMENT    ALL USERS ACCESSING THE GIVEN FILE.
COMMENT
COMMENT --------------------------------------
COMMENT -->  ENTER 'ACESTELL ?' FOR HELP.  <--
COMMENT --------------------------------------
COMMENT
COMMENT                        KIM HECKLER  11/98
COMMENT                    hecklek@gatesmcdonald.com
COMMENT ***********************************************

IF  "!accfile" = "?"
  ECHO
  ECHO ACESTELL - Sends the given tell message to all sessions
  ECHO            accessing the given file.
  ECHO
  ECHO Syntax -
  ECHO
  ECHO   :ACESTELL filename,typem,message
  ECHO
  ECHO Parameters -
  ECHO
  ECHO   filename - the file name that is being accessed,
  ECHO              qualified to the desired level.
  ECHO              (REQUIRED)
  ECHO      typem - type of message desired
  ECHO               T = TELL message (DEFAULT),
  ECHO               W = MPEX WARNF message (MUST HAVE OP CMDS ALLOWED).
  ECHO              (OPTIONAL)
  ECHO    message - the message you want sent to each session(s).
  ECHO              (REQUIRED)
  ECHO
ELSE
  SETVAR typem UPS('!typem')
  IF typem = 'T' OR typem = 'W'
    IF LEN('!msg') > 0
      IF FINFO('!accfile','EXISTS')
        IF FINFO('!accfile','ACCESSORS') > 0
          PURGE USERLIST,TEMP > $NULL
          LISTFILE !accfile,8 > USERLIST
          XEQ IDSESS !typem !msg < USERLIST
        ELSE
          ECHO
          ECHO File is not currently being accessed!
          ECHO
        ENDIF
      ELSE
        ECHO
        ECHO File does not exist!
        ECHO
      ENDIF
    ELSE
      ECHO
      ECHO Message parm is required!
      ECHO Type 'ACESTELL' for help.
      ECHO
    ENDIF
  ELSE
    ECHO
    ECHO Typem parm must be a 'T' or 'W'.
    ECHO
  ENDIF
ENDIF

DELETEVAR accfile > $NULL
DELETEVAR msg > $NULL
DELETEVAR typem > $NULL
COMMENT    PURGE USERLIST,TEMP > $NULL

</pre>



-- Main.ChrisBartram - 09 Jun 2006