%META:TOPICINFO{author="ChrisBartram" date="1149893817" format="1.1" version="1.1"}%
%META:TOPICPARENT{name="Hp3000MpexXeqs"}%
<pre>
!JOB HISTORY,USER.ACCOUNT;OUTCLASS=LP,1,1
!
!####################################################################
!#
!# AUTHOR      : JEFF HANSON -- DENKOR CORP.
!#
!# DESCRIPTION : THE PURPOSE OF THIS JOB STREAM IS TO MOVE
!# TRANSACTIONS FROM TRANS.CLNDB TO TRANS.HSTDB.
!#
!# PRIOR TO THE HISTORY MOVE THE CAPACITIES OF THE HSTDB DATASETS
!# MUST BE SUFFICEINTLY LARGE TO HANDLE THE NEW ENTRIES.  NOT ONLY
!# MUST THE TRANS.HSTDB DATASET BE LARGE ENOUGH, THE ASSOCIATED
!# AUTOMATIC MASTERS MUST BE ENLARGED AS WELL. (NOT SHOWN HERE)
!#
!####################################################################
!
!####################################################################
!#
!# EXTRACT THE ENTRIES FROM CLNDB AND PUT THEM INTO A QUIZ SUBFILE.
!# CALCULATE THE POSSIBLE NUMBER OF ENTRIES THAT COULD BE ADDED TO
!# HSTDB THAT ARE NOT ALREADY THERE.
!#
!####################################################################
!
!QUIZ HIST1.OBJR.COGACCT
!
!SUPRTOOL
USE HIST2.SUPRUSE.COGACCT
XEQ
EXIT
!
!SHOWVAR SUPR@
!
!SETVAR H_NEW_COUNT SUPRTOOLFULLCOUNT
!
!####################################################################
!#
!# USE THE NUMBER GENERATED BY THE SUPRTOOL PASS ABOVE AND THE
!# NUMBERS GENERATED BELOW TO CALCULATE A NEW RATIO FOR THE DBADGALT
!# COMMAND.  MAKE THE HSTDB DATASET SUFFICIENTLY LARGE TO HANDLE THE
!# MAX POSSIBLE NUMBER OF ENTRIES TO BE MOVED.  THE HSTDB DATASET
!# WILL BE ALTERED TO A SPACE SAVING CAPACITY AFTER THE HISTORY
!# PROCESS IS COMPLETE.
!#
!####################################################################
!
!MPEX

SETVAR H_ENTRY_COUNT,VEFINFO("HSTDB02.PUB").DBSETENTRIES
SETVAR H_CAP_COUNT,VEFINFO  ("HSTDB02.PUB").DBSETCAPACITY
SETVAR H_NEWCAP_COUNT       (!H_CAP_COUNT+!H_NEW_COUNT)
SETVAR H_FUDGE_FACTOR       (30)

SHOWVAR H_@

CALC ![ !H_ENTRY_COUNT // ( !H_NEWCAP_COUNT + &
      ( !H_NEWCAP_COUNT * ( !H_FUDGE_FACTOR // 100 )))]

DBADGALT HSTDB02.PUB, ![ !H_ENTRY_COUNT // ( !H_NEWCAP_COUNT + &
                       ( !H_NEWCAP_COUNT * ( !H_FUDGE_FACTOR // 100 )))]

EXIT                 
!
!####################################################################
!#
!# CLEAN UP THE SYSTEM VARIABLES
!#
!####################################################################
!
!DELETEVAR H_NEW_COUNT
!DELETEVAR H_ENTRY_COUNT
!DELETEVAR H_CAP_COUNT
!DELETEVAR H_NEWCAP_COUNT
!DELETEVAR H_FUDGE_FACTOR
!
!LX HSTDB@.PUB,DBX
!
!####################################################################
!#
!#           POST THE ENTRIES TO HSTDB
!#
!####################################################################
!
!QTP HIST3.OBJQ.COGACCT
!
!####################################################################
!#
!#                     SUBFILE CLEAN UP
!#
!####################################################################
!
!PURGE HIST1.SUBFILE
!
!SQUEEZE HIST@.SUBFILE
!
!LX HSTDB@.PUB,DBX
!
!####################################################################
!#
!#  SET THE HSTDB DATASETS INVOLVED IN THE HISTORY PROCESS TO AN
!#  ARCHIVAL CAPACITY.  EXCEPT FOR THE HISTORY PROCESS, HSTDB IS
!#  STATIC IN ACTIVITY.
!#
!####################################################################
!
!MPEX
DBADGALT HSTDB02.PUB, .9
EXIT
!
!LX HSTDB@,DBX
!
!EOJ

</pre>



-- Main.ChrisBartram - 09 Jun 2006